Las traducciones son generadas a través de traducción automática. En caso de conflicto entre la traducción y la version original de inglés, prevalecerá la version en inglés.

# Creación de una AMI personalizada con Terraform
<a name="tutorial-create-ami-terraform"></a>

Al usarlo AWS ParallelCluster, solo paga por los AWS recursos que se crean al crear o actualizar AWS ParallelCluster imágenes y clústeres. Para obtener más información, consulte [AWS servicios utilizados por AWS ParallelCluster](aws-services-v3.md).

**Requisitos previos**
+  Está instalado Terraform v1.5.7\$1. 
+ [AWS ParallelCluster API](api-reference-v3.md) v3.8.0\$1 está implementada en su cuenta. Consulte [Creación de un clúster con Terraform](tutorial-create-cluster-terraform.md). 
+ Función de IAM con los permisos para invocar la ParallelCluster API. Consulte [Permisos necesarios](tutorial-create-ami-terraform-permissions.md).

# Definición de un proyecto de Terraform
<a name="tutorial-create-ami-terraform-define"></a>

En este tutorial, definirá un proyecto sencillo de Terraform para implementar una AMI ParallelCluster personalizada.

1. Cree un directorio denominado `my-amis`. 

   Todos los archivos que cree estarán dentro de este directorio.

1. Cree el archivo `terraform.tf` para importar el ParallelCluster proveedor.

   ```
   terraform {
     required_version = ">= 1.5.7"
     required_providers {
       aws-parallelcluster = {
         source  = "aws-tf/aws-parallelcluster"
         version = "~> 1.0"
       }
     }
   }
   ```

1. Cree el archivo `providers.tf` para configurar los AWS proveedores ParallelCluster y.

   ```
   provider "aws" {
     region  = var.region
     profile = var.profile
   }
   
   provider "aws-parallelcluster" {
     region         = var.region
     profile        = var.profile
     api_stack_name = var.api_stack_name
     use_user_role  = true
   }
   ```

1. Cree el archivo `main.tf` para definir los recursos mediante el ParallelCluster módulo.

   Para revisar las propiedades de la imagen que puede establecer en el elemento `image_configuration`, consulte [Cree archivos de configuración de imágenes](image-builder-configuration-file-v3.md).

   Para revisar las opciones que puede configurar para la creación de imágenes, por ejemplo `image_id` y `rollback_on_failure`, consulte [`pcluster build-image`](pcluster.build-image-v3.md). 

   ```
   data "aws-parallelcluster_list_official_images" "parent_image" {
     region = var.region
     os = var.os
     architecture = var.architecture
   }
   
   resource "aws-parallelcluster_image" "demo01" {
     image_id            = "demo01"
     image_configuration = yamlencode({
       "Build":{
         "InstanceType": "c5.2xlarge",
         "ParentImage": data.aws-parallelcluster_list_official_images.parent_image.official_images[0].amiId,
         "UpdateOsPackages": {"Enabled": false}
       }
     })
     rollback_on_failure = false
   }
   ```

1. Cree el archivo `variables.tf` para definir las variables que se pueden inyectar en este proyecto.

   ```
   variable "region" {
     description = "The region the ParallelCluster API is deployed in."
     type        = string
     default     = "us-east-1"
   }
   
   variable "profile" {
     type        = string
     description = "The AWS profile used to deploy the clusters."
     default     = null
   }
   
   variable "api_stack_name" {
     type        = string
     description = "The name of the CloudFormation stack used to deploy the ParallelCluster API."
     default     = "ParallelCluster"
   }
   
   variable "api_version" {
     type        = string
     description = "The version of the ParallelCluster API."
   }
   
   variable "os" {
     type        = string
     description = "The OS of the ParallelCluster image."
   }
   
   variable "architecture" {
     type        = string
     description = "The architecture of the ParallelCluster image."
   }
   ```

1. Cree el archivo `terraform.tfvars` para establecer los valores arbitrarios de las variables. 

   Con el siguiente archivo, implemente la AMI personalizada `us-east-1` basada en la arquitectura Amazon Linux 2 para x86\$164, utilizando la ParallelCluster API 3.11.1 existente que ya está implementada con el nombre de la pila. `us-east-1` `MyParallelClusterAPI-3111`

   ```
   region = "us-east-1"
   api_stack_name = "MyParallelClusterAPI-3111"
   api_version = "3.11.1"
   
   os = "alinux2"
   architecture = "x86_64"
   ```

1. Cree el archivo `outputs.tf` para definir los resultados devueltos por este proyecto.

   ```
   output "parent_image" {
     value = data.aws-parallelcluster_list_official_images.parent_image.official_images[0]
   }
   
   output "custom_image" {
     value = aws-parallelcluster_image.demo01
   }
   ```

   El directorio del proyecto es el siguiente:

   ```
   my-amis
   ├── main.tf - Terraform entrypoint where the ParallelCluster module is configured.
   ├── outputs.tf - Defines the cluster as a Terraform output.
   ├── providers.tf - Configures the providers: ParallelCluster and AWS.
   ├── terraform.tf - Import the ParallelCluster provider.
   ├── terraform.tfvars - Defines values for variables, e.g. region, PCAPI stack name.
   └── variables.tf - Defines the variables, e.g. region, PCAPI stack name.
   ```

# Implementación de la API
<a name="tutorial-create-ami-terraform-deploy"></a>

Para implementar la AMI, ejecute los comandos estándar de Terraform en orden.

1. Compile el proyecto:

   ```
   terraform init
   ```

1. Defina el plan de implementación:

   ```
   terraform plan -out tfplan
   ```

1. Implemente el plan:

   ```
   terraform apply tfplan
   ```

# Permisos necesarios
<a name="tutorial-create-ami-terraform-permissions"></a>

Necesita los siguientes permisos para implementar una AMI personalizada con Terraform:
+ asuma la función de ParallelCluster API, que se encarga de interactuar con la ParallelCluster API
+ describa la CloudFormation pila de la ParallelCluster API para verificar su existencia y recuperar sus parámetros y resultados

------
#### [ JSON ]

****  

```
{
    "Version":"2012-10-17",		 	 	 
    "Statement": [
        {
            "Action": "sts:AssumeRole",
            "Resource": "arn:aws:sts::111122223333:role/PCAPIUserRole-*",
            "Effect": "Allow",
            "Sid": "AssumePCAPIUserRole"
        },
        {
            "Action": [
                "cloudformation:DescribeStacks"
            ],
            "Resource": "arn:aws:cloudformation:us-east-1:111122223333:stack/*",
            "Effect": "Allow",
            "Sid": "CloudFormation"
        }
    ]
}
```

------